home *** CD-ROM | disk | FTP | other *** search
/ Whiteline: delta / whiteline CD Series - delta.iso / vision / povray / demo / arealit3.pov < prev    next >
Text File  |  1995-11-25  |  2KB  |  89 lines
  1. // Persistence Of Vision raytracer version 2.0 sample file.
  2. // Illustrates how adaptive level can affect soft shadows
  3.  
  4. // The shadow on the left uses "adaptive 0" and shows some major shadow
  5. // artifacts causes by undersampling. As the adaptive level increases
  6. // the shadow become much more accurate. Note: This is a worst-case
  7. // example.
  8.  
  9. // Left   shadow - adaptive 0 (renders fastest)
  10. // Middle shadow - adaptive 1
  11. // Right  shadow - adaptive 2 (renders slowest)
  12.  
  13. #include "colors.inc"
  14. #include "textures.inc"
  15.  
  16. // A back wall to cast shadows onto
  17. plane { -z, -20
  18.     pigment { Gray70 }
  19.     finish { Dull }
  20. }
  21.  
  22. #declare SpacingX = 20
  23. #declare Radius = 5
  24. #declare LightX = 15
  25. #declare LightY = 40
  26. #declare LightZ = -40
  27. #declare SRadius = 0
  28. #declare SFalloff = 11
  29.  
  30. #declare Object = difference {
  31.     box { <-6, -6, 0>, <6, 6, 0.5> rotate 45*z }
  32.     box { <-2.5, -2.5, -1>, <2.5, 2.5, 1> rotate 45*z }
  33.     pigment { Red }
  34.     finish { Shiny }
  35. }
  36.  
  37. object { Object translate -SpacingX*x }
  38.  
  39. light_source {
  40.     <0, LightY, LightZ> color White
  41.     area_light <15, 0, 0>, <0, 15, 0>, 17, 17
  42.     adaptive 0
  43.     jitter
  44.  
  45.     spotlight
  46.     point_at <-SpacingX, 0, 0>
  47.     tightness 0
  48.     radius SRadius
  49.     falloff SFalloff
  50. }
  51.  
  52. object { Object translate 0*x }
  53.  
  54. light_source {
  55.     <0, LightY, LightZ> color White
  56.     area_light <15, 0, 0>, <0, 15, 0>, 17, 17
  57.     adaptive 1
  58.     jitter
  59.  
  60.     spotlight
  61.     point_at <0, 0, 0>
  62.     tightness 0
  63.     radius SRadius
  64.     falloff SFalloff
  65. }
  66.  
  67. object { Object translate SpacingX*x }
  68.  
  69. light_source {
  70.     <0, LightY, LightZ> color White
  71.     area_light <15, 0, 0>, <0, 15, 0>, 17, 17
  72.     adaptive 2
  73.     jitter
  74.  
  75.     spotlight
  76.     point_at <+SpacingX, 0, 0>
  77.     tightness 0
  78.     radius SRadius
  79.     falloff SFalloff
  80. }
  81.  
  82. light_source { <0, -15, -120> color Gray10 }
  83.  
  84. camera {
  85.     location <0, -15, -120>
  86.     direction 2*z
  87.     look_at <0, -15, 0>
  88. }
  89.